Initial dendritic rewrite

packages/heybrochecklog.nix

@@ -0,0 +1,44 @@
+{
+  lib,
+  python3Packages,
+  fetchFromGitHub,
+  ...
+}:
+with python3Packages;
+
+buildPythonApplication rec {
+  pname = "heybrochecklog";
+  version = "v1.4.7";
+
+  src = fetchFromGitHub {
+    owner = "doujincafe";
+    repo = "hbcl";
+    rev = version;
+    sha256 = "sha256-LB2Xn6oS3iBL/+1vMRuj0cmRc9tRiCjgJ5axm4tYkdg=";
+  };
+
+  format = "pyproject";
+  doCheck = false;
+
+  nativeBuildInputs = [
+    poetry-core
+  ];
+
+  propagatedBuildInputs = [
+    faust-cchardet
+    chardet
+    pprp # Comes from the overlay, not part of nixpkgs
+  ];
+
+  postPatch = ''
+    substituteInPlace pyproject.toml \
+      --replace 'poetry.masonry.api' 'poetry.core.masonry.api' \
+      --replace 'poetry>=' 'poetry-core>='
+  '';
+
+  meta = {
+    description = "A doujin café discord community maintained log checker";
+    homepage = "https://github.com/doujincafe/hbcl";
+    license = lib.licenses.asl20;
+  };
+}

packages/monique.nix

@@ -0,0 +1,45 @@
+{
+  lib,
+  python3Packages,
+  fetchPypi,
+  libadwaita,
+  gtk4,
+  wrapGAppsHook4,
+  gobject-introspection,
+  ...
+}:
+with python3Packages;
+
+buildPythonApplication rec {
+  pname = "monique";
+  version = "0.5.0";
+
+  src = fetchPypi {
+    inherit pname version;
+    sha256 = "sha256-fA2mVMjAg1vOpHPJr2B0NtJ00cEs23/Y4S4h3WurpY4=";
+  };
+
+  pyproject = true;
+  build-system = [ setuptools ];
+
+  nativeBuildInputs = [
+    wrapGAppsHook4
+    gobject-introspection
+  ];
+
+  buildInputs = [
+    libadwaita
+    gtk4
+  ];
+
+  propagatedBuildInputs = [
+    pygobject3
+  ];
+
+  meta = {
+    description = "Graphical monitor configurator for Hyprland and Sway";
+    homepage = "https://github.com/ToRvaLDz/monique";
+    license = lib.licenses.gpl3;
+    platforms = lib.platforms.linux;
+  };
+}

packages/pprp.nix

@@ -0,0 +1,27 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchPypi,
+  ...
+}:
+
+buildPythonPackage rec {
+  pname = "pprp";
+  version = "0.2.7";
+
+  src = fetchPypi {
+    inherit pname version;
+    sha256 = "sha256-2ednecxSsJONvH9XJ6GV3ExgdcPrUEAlYRpZt2Nrkw0=";
+  };
+
+  format = "setuptools";
+  doCheck = false;
+
+  pythonImportsCheck = [ "pprp" ];
+
+  meta = {
+    description = "A pure-Python Rijndael (AES) and PBKDF2 library";
+    homepage = "https://github.com/dsoprea/RijndaelPbkdf";
+    license = lib.licenses.gpl2;
+  };
+}

packages/pywalfox-native.nix

@@ -0,0 +1,28 @@
+{
+  lib,
+  python3Packages,
+  fetchurl,
+  ...
+}:
+with python3Packages;
+
+buildPythonApplication rec {
+  pname = "pywalfox-native";
+  version = "2.8.0rc1";
+  pyproject = true;
+
+  src = fetchurl {
+    url = "https://test-files.pythonhosted.org/packages/89/a1/8e011e2d325de8e987f7c0a67222448b252fc894634bfa0d3b3728ec6dbf/pywalfox-${version}.tar.gz";
+    sha256 = "sha256-ieDXpEHrYAkzRAxxPN2/rs2iNr3n8/ZV2w7CCwrhKEU=";
+  };
+
+  build-system = [ setuptools ];
+
+  pythonImportsCheck = [ "pywalfox" ];
+
+  meta = {
+    description = " Native app used alongside the Pywalfox addon";
+    homepage = "https://github.com/Frewacom/pywalfox-native";
+    license = lib.licenses.mpl20;
+  };
+}